DataGrip extractor for txt file with fixed length columns

Fixed-length-fields.txt.groovy

SEPARATOR = "|"
SPACE = " "
CORNER = "+"
LINE = "-"
NEWLINE = System.getProperty("line.separator")

def outRecord(columnLengths, row, separator=SEPARATOR, padding=SPACE) {
    OUT.append(separator)
    [columnLengths, row].transpose().each { size, value ->
        OUT.append(padding + value.padRight(size, padding) + padding + separator)
    };
    OUT.append(NEWLINE)
}

if (!TRANSPOSED) {
    COLUMN_NAMES = COLUMNS.collect { col -> col.name() }

    def formattedRows = ROWS.collect { row -> COLUMNS.collect { col -> FORMATTER.format(row, col) } }
    def columnLengths = formattedRows.inject(COLUMN_NAMES.collect { col -> col.size() }, { columnLengths, row ->
        [columnLengths, row.collect { it.length() }].transpose().collect { collectedSize, size -> Math.max(collectedSize, size) }
    })

    // OUTPUT

    // HEADER
    outRecord(columnLengths, COLUMNS.collect { '' }, CORNER, LINE)
    outRecord(columnLengths, COLUMN_NAMES)

    outRecord(columnLengths, COLUMNS.collect { '' }, CORNER, LINE)
    formattedRows.each { row -> outRecord(columnLengths, row) }
    outRecord(columnLengths, COLUMNS.collect { '' }, CORNER, LINE)
} else {
    def formattedRows = COLUMNS.collect { col -> new ArrayList<String>([col.name()]) }
    ROWS.each { row -> COLUMNS.eachWithIndex { col, i -> formattedRows[i].add(FORMATTER.format(row, col)) } }

    def columnLengths = (0..formattedRows[0].size-1).collect { idx -> formattedRows.inject(0, { collectedSize, row -> Math.max(collectedSize, row[idx].length()) } ) }

    // OUTPUT

    outRecord(columnLengths, COLUMNS.collect { '' }, CORNER, LINE)
    formattedRows.each { row -> outRecord(columnLengths, row) }
    outRecord(columnLengths, COLUMNS.collect { '' }, CORNER, LINE)
}

Exactly what I wanted, despite this limitation. Thanks for taking the time to post this!