.scm

;; (match-let ((pattern values) ...) body)
(macro (match-let form)
       (letrec
         ((match (lambda (var val)
                   (cond
                     ((symbol? var)
                      `((,var ,val)))
                     ((pair? var)
                      `(,@(match (car var) `(car ,val))
                         ,@(match (cdr var) `(cdr ,val))))
                     ((vector? var)
                      (let next ((i 0))
                        `(,@(match (vector-ref var i) `(vector-ref ,val ,i))
                           ,@(if (< (+ 1 i) (vector-length var))
                                 (next (+ 1 i)) '()))))
                     (#t '())
                     ))))
         (let ((vars (map car (cadr form)))
               (vals (map cadr (cadr form)))
               (body (cddr form))
               (sym (gensym)))
           `(let ((,sym (list ,@vals)))
              (let ,(match vars sym) ,@body)))))

; (match-let (((non-empty x0 y0 x1 y1)
;              (gimp-selection-bounds img)))
;            (print `(width ,(- x1 x0)))
;            (print `(height ,(- y1 y0)))
;            '... )