bannerclock.apl

#!/usr/bin/apl -s
⍝ klg, Dec 2017

FONT←'#'=⍪⌿{((¯1↑⍴⍵)⍴8↑1)/⍵} 8,/⍪¨⊃ ⎕INP 'ENDFONT'
.......:..##...:.####..:.####..:....##.:######.:..###..:######.:.####..:.####..:.####..:.......:
.......:.###...:##..##.:##..##.:##..##.:##.....:.##....:....##.:##..##.:##..##.:##..##.:.......:
.......:..##...:....##.:....##.:##..##.:#####..:##.....:...##..:##..##.:##..##.:##..##.:..##...:
.......:..##...:..###..:...##..:##..##.:....##.:#####..:..##...:.####..:.#####.:##..##.:.......:
.......:..##...:.##....:....##.:######.:....##.:##..##.:.##....:##..##.:....##.:##..##.:.......:
.......:..##...:##.....:##..##.:....##.:##..##.:##..##.:.##....:##..##.:...##..:##..##.:..##...:
.......:.####..:######.:.####..:....##.:.####..:.####..:.##....:.####..:.###...:.####..:.......:
ENDFONT

∇R←C fmt S
 →(0≠⎕NC'C')/⎕LC+1 ⋄ C←' █'
  R←C[⎕IO+⊃,/FONT[' 1234567890:'⍳S]]
∇

∇S←PW center S;W
 →(0≠⎕NC'PW')/⎕LC+1 ⋄ PW←⎕PW
  S←(-W+⌊(PW-W←¯1↑⍴S)÷2)↑[⎕IO+¯1+⍴⍴S]S
∇

∇ main ;S;HO;EL;ED
  HO←↑⍎')HOST tput home'
  EL←↑⍎')HOST tput el'
  ED←↑⍎')HOST tput ed'
 NEXT:
  ⊣⎕DL 1-(7⊃⎕TS)÷1000
  S←⊂[2] center fmt '46:06:06'⍕⎕TS[4 5 6]
  ⍞←∊{HO,⍵,ED}{⍺,EL,"\n",⍵}/" ",S
 →NEXT
∇

'Interrupt to quit...'
')OFF' ⎕EA 'main'