https://twitter.com/a_thieriot/status/303966663592779776

notes.md

Notes about your presentation draft

As kindly requested :)

• http://aurelien.thier.io/casperjs-ghost-tour/#selectors: you should mention the import of var x = require('casper').selectXPath
• on the same slide, it probably misses a run() final call
• http://aurelien.thier.io/casperjs-ghost-tour/#evaluates: you may want to mention the remoteScripts option as well
• on the same slide, this.test.assertEval(function(title)}, 'google.fr title is "Google"', 'Google'); should be this.test.assertEval(function(title)}, 'Google', 'google.fr title is "Google"');
• http://aurelien.thier.io/casperjs-ghost-tour/#debug: you should mention the existence of a bookmarklet
• http://aurelien.thier.io/casperjs-ghost-tour/#more: maybe add the link to the casperjs github org listing its whole ecosystem: https://github.com/casperjs

Other than that, great presentation, all the best :)

PS: I slightly rewrote your demo example and added a 1.1-dev version, see below

test-1.0.coffee

# to be executed using $ casperjs test test-1.0.coffee --direct --log-level=debug

casper.options.clientScripts = ["includes/underscore-min.js"]

testedName = 'Aurelien'
testedRepetition = 5

casper.start 'http://localhost:9000/', () ->
    @test.assertTitle 'The "helloworld" application', 'hello world application expected'
    @test.assertTextExists 'Configure', 'you can configure the app'

    @fill 'form[action="/hello"]', 
        name: testedName
        repeat: testedRepetition
        color: 'red'
    , true

casper.then () ->
    @test.assertTitle 'Here is the result:', 'result page expected'

casper.then () ->
    @test.assertTextExists "Hello #{testedName}!", 'message displayed correctly'
    @test.assertUrlMatch /name=Aurelien/, 'search term has been submitted'

    @capture 'page.png'

    @test.assertEval (times, name) -> 
       elements = __utils__.findAll 'li'
       return false if elements.length is not times
       _.every elements, (e) ->
          e.textContent is "Hello #{name}!"
    , "message displayed more that #{testedRepetition} times"
    , [testedRepetition, testedName]

casper.thenClick '.buttons a', () ->
    @test.assertTitle 'The "helloworld" application', 'hello world application expected'

casper.back () ->
    @test.assertTitle 'Here is the result:', 'result page expected'

casper.run () ->
    @test.done 8     #checks that 7 assertions have been executed
    @test.renderResults true

test-1.1-dev.coffee

# to be executed using $ casperjs test test-1.1-dev.coffee --direct --log-level=debug

casper.options.clientScripts = ["includes/underscore-min.js"]

casper.test.begin "Aurelien's site tests", 8, (test) ->
    testedName = 'Aurelien'
    testedRepetition = 5
    
    casper.start 'http://localhost:9000/', () ->
        test.assertTitle 'The "helloworld" application', 'hello world application expected'
        test.assertTextExists 'Configure', 'you can configure the app'
    
        @fill 'form[action="/hello"]', 
            name: testedName
            repeat: testedRepetition
            color: 'red'
        , true
    
    casper.then () ->
        test.assertTitle 'Here is the result:', 'result page expected'
    
    casper.then () ->
        test.assertTextExists "Hello #{testedName}!", 'message displayed correctly'
        test.assertUrlMatch /name=Aurelien/, 'search term has been submitted'
    
        @capture 'page.png'
    
        test.assertEval (times, name) -> 
           elements = __utils__.findAll 'li'
           return false if elements.length is not times
           _.every elements, (e) ->
              e.textContent is "Hello #{name}!"
        , "message displayed more that #{testedRepetition} times"
        , [testedRepetition, testedName]
    
    casper.thenClick '.buttons a', () ->
        test.assertTitle 'The "helloworld" application', 'hello world application expected'
    
    casper.back () ->
        test.assertTitle 'Here is the result:', 'result page expected'
    
    casper.run () -> test.done()