gistfile1.pde

// by dw don't steal >:)

int[][] result;
float t;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3);

void setup() {
  setup_();
  result = new int[width*height][3];
}

void draw() {
  
  if(!recording){
    t = mouseX*1.0/width;
    draw_();
  }
  
  else {
  for (int i=0; i<width*height; i++)
    for (int a=0; a<3; a++)
      result[i][a] = 0;

  for (int sa=0; sa<samplesPerFrame; sa++) {
    t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
    draw_();
    loadPixels();
    for (int i=0; i<pixels.length; i++) {
      result[i][0] += pixels[i] >> 16 & 0xff;
      result[i][1] += pixels[i] >> 8 & 0xff;
      result[i][2] += pixels[i] & 0xff;
    }
  }

  loadPixels();
  for (int i=0; i<pixels.length; i++)
    pixels[i] = 0xff << 24 | 
      int(result[i][0]*1.0/samplesPerFrame) << 16 | 
      int(result[i][1]*1.0/samplesPerFrame) << 8 | 
      int(result[i][2]*1.0/samplesPerFrame);
  updatePixels();

  saveFrame("f###.gif");
  if (frameCount==numFrames)
    exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 8;
int numFrames = 120;        
float shutterAngle = .6;

boolean recording = false;

void setup_() {
  size(660,500,P3D);
  stroke(32);
  strokeWeight(2.2);
  smooth(8);
  noFill();
}

float x, y, z;
int N = 1200;
float r = 150, th, ph;

void draw_() {
  background(250); 
  pushMatrix();
  translate(width/2, height/2);
  rotateX(-QUARTER_PI);
  rotate(HALF_PI);
  beginShape();
  for(int i=0; i<N; i++){
    th = PI*i/N;
    ph = -42*th - 3*TWO_PI*t;
    
    y = r*sin(th)*cos(ph);
    z = r*sin(th)*sin(ph);
    x = r*cos(th);
    
    x += (sin(th))*cos(TWO_PI*t + th*2)*24;
    
    vertex(x,y,z);
  }
  endShape();
  popMatrix();
}