gistfile1.pde

// by david whyte >:)

int[][] result;
float t;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3);

void setup() {
  setup_();
  result = new int[width*height][3];
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 4;
int numFrames = 150;        
float shutterAngle = .7;

boolean recording = true;

void setup_() {
  size(500,
  500, P2D);
  smooth(8);
  stroke(32);
  noFill();
  strokeWeight(3.5);
}

float x, y, tt;
int N = 16;
float r = 16;
int n = 4;
float sp = 4.5*r;
float th;
float cx, cy;

void thing(float q) {
  pushMatrix();
  beginShape();
  for (int i=0; i<N; i++) {
    tt = map(cos(TWO_PI*q + HALF_PI*i/(N-1)),1,-1,0,1);
    tt = ease(constrain(1.5*tt - 0.25,0,1),1.8);
    th = map(i, 0, N-1, -QUARTER_PI, QUARTER_PI);
    x = r*sin(th);
    y = lerp(r*cos(th), .5*sp-r*cos(th), tt);
    vertex(x, y);
  }
  endShape();
  popMatrix();
}

void draw_() {
  background(250); 
  pushMatrix();
  translate(width/2, height/2);
  for (int a=-n; a<=n; a++) {
    for (int b=-2*n; b<=2*n; b++) {
      pushMatrix();
      cx = a*sp;
      cy = b*.5*sp;
      if(b%2 != 0)
        cx += .5*sp;
      translate(cx, cy);
      
      for (int i=0; i<4; i++) {
        pushMatrix();
        rotate(HALF_PI*i);
        thing(t - 0.0008*sqrt(cx*cx+cy*cy));
        popMatrix();
      }
      popMatrix();
    }
  }
  popMatrix();
}