gistfile1.pde

// by david whyte

int[][] result;
float t;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3);

void setup() {
  setup_();
  result = new int[width*height][3];
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 8;
int numFrames = 160;        
float shutterAngle = .6;

boolean recording = false;

void setup_() {
  size(500, 500);
  fill(32);
  noStroke();
  smooth(8);
}

void lens() {
  arc(-r*sqrt(.5)-.5, 0, 2*r, 2*r, -QUARTER_PI, QUARTER_PI, CHORD);
  arc(r*sqrt(.5)+.5, 0, 2*r, 2*r, PI-QUARTER_PI, PI+QUARTER_PI, CHORD);
}

float th(float q){
  if(q<.5)
    return HALF_PI*ease(min(1,2*map(q,0,.5,0,1)),2.5);
  else
    return HALF_PI + HALF_PI*ease(min(1,2*map(q,.5,1,0,1)),2.5);
}

float x, y, tt;
int N = 7;
float r = 36, sp = r*sqrt(2);
float th;

void draw_() {
  background(250); 
  pushMatrix();
  translate(width/2, height/2);
  for (int i=-N; i<=N; i++) {
    for (int j=-N; j<=N; j++) {
      x = (i+.5)*sp;
      y = j*sp;
      tt = t + 10 - 0.0007*(abs(x)+abs(y));
      tt %= 1;
      pushMatrix();
      translate(x, y);
      rotate(th(tt));
      lens();
      popMatrix();
      x = i*sp;
      y = (j+.5)*sp;
      tt = t + 10 - 0.0007*(abs(x)+abs(y));
      tt %= 1;
      pushMatrix();
      translate(x, y);
      rotate(th(tt)+HALF_PI);
      lens();
      popMatrix();
    }
  }
  popMatrix();
  
}