gistfile1.pde

// by bees & bombs (:<

int[][] result;
float t;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3);

void setup() {
  setup_();
  result = new int[width*height][3];
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 32;
int numFrames = 120;        
float shutterAngle = .6;

boolean recording = true;

void setup_() {
  size(500, 500, P3D);
  smooth(8);
  rectMode(CENTER);
  stroke(32);
  noFill();
  strokeWeight(1.0);
}

float x, y, z, tt;
float r = 144;
float th;
int N = 24, n = 180;
float ll = .00015, rr;
float h = 80;

void draw_() {
  background(250); 
  pushMatrix();
  translate(width/2, height/2 - 20);
  rotateX(.9);
  rotate(-PI/3+HALF_PI*t);
  for (int i=0; i<N; i++) {
    x = map(i, -.5, N-.5, -r, r);
    beginShape();
    for (int j=0; j<n; j++) {
      y = map(j, 0, n-1, -r, r);
      y = constrain(y, -sqrt(r*r-x*x), sqrt(r*r-x*x));
      rr = dist(x, y, 0, 0);
      z = map(cos(ll*rr*rr - TWO_PI*t), -1, 1, 0, h);

      vertex(x, y, z);
    }
    endShape();
    beginShape();
    for (int j=0; j<n; j++) {
      y = map(j, 0, n-1, -r, r);
      y = constrain(y, -sqrt(r*r-x*x), sqrt(r*r-x*x));
      rr = dist(x, y, 0, 0);
      z = map(cos(ll*rr*rr - TWO_PI*t), -1, 1, 0, h);
      vertex(y, x, z);
    }
    endShape();
  }

  beginShape();
  for (int i=0; i<3*n; i++) {
    th = i*TWO_PI/(3*n);
    x = r*cos(th);
    y = r*sin(th);
    z = map(cos(ll*r*r - TWO_PI*t), -1, 1, 0, h);
    vertex(x, y, z);
  }
  endShape(CLOSE);
  popMatrix();
}