ARサンプル３

ar_sample03.pde

/*****************************************
* AR勉強会　サンプル３
*
* Processing2.2.1 with nyar4psg 2.1.0
* 
* Hiroyuki Nakano
* 2015.2.3
*****************************************/

import processing.video.*;
import jp.nyatla.nyar4psg.*;

Capture cam;
MultiMarker nya;

void setup() {
  size(640, 480, P3D);
  colorMode(RGB, 255);
  cam=new Capture(this, 640, 480);
  nya=new MultiMarker(this, width,height, "camera_para.dat", NyAR4PsgConfig.CONFIG_PSG);
  nya.addNyIdMarker(1,80); // IDマーカー（１番）を使う（マーカー設定番号は 0 になる）
  nya.addNyIdMarker(2,80); // IDマーカー（２番）を使う（マーカー設定番号は 1 になる）
  cam.start();
}

void draw(){
  // カメラが使用不可なら処理をしない
  if (cam.available() !=true) {
      return;
  }

  // カメラが使用可能なら以下の処理をする
  cam.read();
  nya.detect(cam);
  background(0);
  nya.drawBackground(cam);

  // IDマーカー（１番）が見つかったとき
  if((nya.isExistMarker(0))){  // カッコ内の 0 はマーカー設定番号
    nya.beginTransform(0);     // マーカー設定番号 0 の位置を基準
      fill(0, 255, 0);         // 塗り色を緑
      stroke(0, 200, 0);       // 線の色を濃い緑
      translate(0, 0, 20);     // Z軸方向に40移動
      sphere(40);              // 半径40の球体を表示
    nya.endTransform();
  }
  // IDマーカー（２番）が見つかったとき
  if((nya.isExistMarker(1))){  // カッコ内の 1 はマーカー設定番号
    nya.beginTransform(1);     // マーカー設定番号 1 の位置を基準
      fill(255, 255, 255);     // 塗り色を白
      stroke(200, 200, 200);   // 線の色を灰色
      translate(0, 0, 30);     // Z軸方向に30移動
      sphere(60);              // 半径60の球体を表示
    nya.endTransform();
  }
}