Power Query function for cleaning pairwise matches on an arbitrary column-set

powerquery-fnCleanNwiseMatch.m

(Data as table, ComparisonColumns as list, ReplacementFunction as function) as table =>
let
    AddRecords = Table.AddColumn(Data, "Record",each _),

    AddSortedComparisonValues = Table.AddColumn(
        AddRecords,
        "SortedComparisonValues",
        each List.Sort(
                Record.FieldValues(
                    Record.SelectFields(_, ComparisonColumns)
                )
            )
    ),

    GetReplacement = Table.Group(
        AddSortedComparisonValues, 
        "SortedComparisonValues", 
        {
            {"ReplacementRecord",
            each ReplacementFunction(Table.SelectColumns(_, ComparisonColumns))}
        }
    ),

    AddReplacementRecord = Table.AddColumn(
        AddSortedComparisonValues,
        "ReplacementRecord",
        each GetReplacement{
            [SortedComparisonValues=[SortedComparisonValues]]
            }[ReplacementRecord]
    ),

    RecordMerge = Table.AddColumn(
        AddReplacementRecord,
        "NewRecord",
        each [Record] & [ReplacementRecord] 
    ),

    Result = Table.FromRecords(RecordMerge[NewRecord])
in
    Result