These Excel LAMBDA functions support extending TRIMRANGE to remove intermediary vectors from sparse references

excel-lambda-TRIMRANGE2.txt

CHECKRANGE = LAMBDA(checkfn,
    LAMBDA(directionfn,
        LAMBDA(v,
            directionfn(v,LAMBDA(x,AND(checkfn(x))))
        )));
CHECKISBLANK = CHECKRANGE(ISBLANK);
CHECKBLANKROWS = CHECKISBLANK(BYROW);
CHECKBLANKCOLS = CHECKISBLANK(BYCOL);

TRIMRANGE2 =LAMBDA(sparseRange, [compressOrRemove], 
    LET(
        rng, TRIMRANGE(sparseRange),
        maskFn, LAMBDA(v,
            MAP(SEQUENCE(ROWS(v)), LAMBDA(i,
                IF(i = 1, TRUE,
                    IF(
                        compressOrRemove,
                        NOT(INDEX(v, i)),
                        OR(
                            NOT(INDEX(v, i)),
                            AND(INDEX(v, i), NOT(INDEX(v, i - 1)))
                        )))))),
        compressRows, FILTER(rng,maskFn(CHECKBLANKROWS(rng))),
        TRANSPOSE(
            FILTER(
                TRANSPOSE(compressRows),
                maskFn(TRANSPOSE(CHECKBLANKCOLS(rng)))
            ))));