si.zig

const std = @import("std");

pub fn Unit(kg_: i32, m_: i32, s_: i32, A_: i32, K_: i32, mol_: i32, cd_: i32) type {
    return struct {
        const This = @This();
        const kg: i32 = kg_;
        const m: i32 = m_;
        const s: i32 = s_;
        const A: i32 = A_;
        const K: i32 = K_;
        const mol: i32 = mol_;
        const cd: i32 = cd_;

        value: f64,

        pub fn add(this: @This(), other: @This()) @This() {
            return .{ .value = this.value + other.value };
        }

        pub fn sub(this: @This(), other: @This()) @This() {
            return .{ .value = this.value - other.value };
        }

        pub fn mul(this: @This(), other: anytype) Mul(@TypeOf(other)) {
            return .{ .value = this.value * other.value };
        }
        fn Mul(Other: type) type {
            return Unit(
                This.kg + Other.kg,
                This.m + Other.m,
                This.s + Other.s,
                This.A + Other.A,
                This.K + Other.K,
                This.mol + Other.mol,
                This.cd + Other.cd,
            );
        }

        pub fn div(this: @This(), other: anytype) Div(@TypeOf(other)) {
            return .{ .value = this.value / other.value };
        }
        fn Div(Other: type) type {
            return Unit(
                This.kg - Other.kg,
                This.m - Other.m,
                This.s - Other.s,
                This.A - Other.A,
                This.K - Other.K,
                This.mol - Other.mol,
                This.cd - Other.cd,
            );
        }
    };
}

// zig fmt: off
pub const Bare      = Unit(0, 0, 0, 0, 0, 0, 0);
pub const Kilograms = Unit(1, 0, 0, 0, 0, 0, 0);
pub const Meters    = Unit(0, 1, 0, 0, 0, 0, 0);
pub const Seconds   = Unit(0, 0, 1, 0, 0, 0, 0);
pub const Amperes   = Unit(0, 0, 0, 1, 0, 0, 0);
pub const Kelvins   = Unit(0, 0, 0, 0, 1, 0, 0);
pub const Moles     = Unit(0, 0, 0, 0, 0, 1, 0);
pub const Candelas  = Unit(0, 0, 0, 0, 0, 0, 1);

pub const Area = Meters.Mul(Meters);
pub const Speed = Meters.Div(Seconds);
pub const Acceleration = Speed.Div(Seconds);

pub const Hertz    = Bare.Div(Seconds);
pub const Newtons  = Kilograms.Mul(Acceleration);
pub const Pascals  = Newtons.Div(Area);
pub const Joules   = Newtons.Mul(Meters);
pub const Watts    = Joules.Div(Seconds);
pub const Coulombs = Seconds.Mul(Amperes);
pub const Volts    = Watts.Div(Amperes);
pub const Farads   = Coulombs.Div(Watts);
pub const Ohms     = Volts.Div(Amperes);
pub const Siemens  = Bare.Div(Ohms);
pub const Webers   = Volts.Mul(Seconds);
pub const Teslas   = Webers.Div(Area);
pub const Henrys   = Webers.Div(Amperes);
// zig fmt: on