Users.cfc

component extends="Admin" {

	function config() {
		super.config();
		verifies(except="index,new,create", params="key", paramsTypes="integer", handler="objectNotFound");
		verifies(post=true, only="create,update,delete");
	}

	function index() { 
    users=model("user").findAll();
	}

	function show() { 
		user=model("user").findByKey(params.key);
		if(!isObject(user)){objectNotFound();}
	}

	function new() {
		user=model("user").new();
	}

	function create() {
		user=model("user").new(params.user);
		if(!user.save()){
			renderView(action="new");
		} else {
			redirectTo(action="index", success="User #user.firstname# #user.lastname# successfully created");
		}
	}

	function edit() {
		user=model("user").findByKey(params.key);
	}

	function update() {
		user=model("user").findByKey(params.key);
		if(user.update(params.user)){
			redirectTo(action="index", success="User #user.firstname# #user.lastname# successfully updated");
		} else {
			renderView(action="edit");
		}
	}

	function delete() {
		user=model("user").deleteByKey(params.key);
		redirectTo(action="index", success="User successfully Deleted");
	}

	function objectNotFound() {
		redirectTo(action="index", error="That User wasn't found");
	}

}