terraria server for raspberry pi 4

terraria-server.nix

{ stdenv, lib, fetchurl, unzip, mono, makeWrapper }:

stdenv.mkDerivation rec {
  pname = "terraria-server";
  version = "1.4.3.2";
  urlVersion = lib.replaceChars [ "." ] [ "" ] version;

  src = fetchurl {
    url = "https://terraria.org/api/download/pc-dedicated-server/terraria-server-${urlVersion}.zip";
    sha256 = "sha256-/OClQTO9iBRQk3iTvYbjG1cCicKIBh+yi2OFpurJx8U=";
  };

  nativeBuildInputs = [ unzip makeWrapper ];

  installPhase = ''
    runHook preInstall

    mkdir -p $out/bin
    rm Linux/System*
    rm Linux/Mono*
    rm Linux/monoconfig
    rm Linux/mscorlib.dll
    cp -r Linux $out/
    makeWrapper ${mono}/bin/mono $out/bin/terraria-server --argv0 terraria-server --add-flags "--server --gc=sgen -O=all $out/Linux/TerrariaServer.exe"

    runHook postInstall
  '';

  meta = with lib; {
    homepage = "https://terraria.org";
    description = "Dedicated server for Terraria, a 2D action-adventure sandbox";
    platforms = [ "aarch64-linux" ];
    license = licenses.unfree;
    maintainers = [ { name = "nicball"; email = "[email protected]"; } ];
  };
}