RTMIDI 2.1.0

gistfile1.txt

# Maintainer: speps <speps at aur dot archlinux dot org>

pkgname=rtmidi
pkgver=2.1.0
pkgrel=1
pkgdesc="A set of C++ classes that provides a common API for realtime MIDI input/output."
arch=(i686 x86_64)
url="http://www.music.mcgill.ca/~gary/rtmidi/"
license=('MIT')
depends=('alsa-lib')
source=("${url}release/$pkgname-$pkgver.tar.gz" $pkgname.pc)
md5sums=('ea4acc28724bc21fb08b6ad5efbc5c36'
         'a959c4a5e7c3f60aff6259d1fed12040')

build() {
  cd "$srcdir/$pkgname-$pkgver"
  ./configure --prefix=/usr --with-alsa
  make

  # utils
  cd tests && make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  # pkg-config
  install -Dm755 rtmidi-config "$pkgdir/usr/bin/rtmidi-config"

  # bin
  for _bin in `find tests -type f -perm 755`; do
    install -Dm755 $_bin "$pkgdir/usr/bin/rtmidi-"`basename $_bin`
  done

  # lib
  install -d "$pkgdir/usr/lib"
  install -Dm755 librtmidi.so.$pkgver "$pkgdir/usr/lib/"
  ln -s "librtmidi.so.$pkgver" "$pkgdir/usr/lib/librtmidi.so.2"
  ln -s "librtmidi.so.$pkgver" "$pkgdir/usr/lib/librtmidi.so"

  # headers
  install -d "$pkgdir/usr/include"
  install -Dm644 RtMidi.h "$pkgdir/usr/include"

  # pkg-config
  install -Dm644 $srcdir/$pkgname.pc \
    "$pkgdir/usr/lib/pkgconfig/$pkgname.pc"

  # docs
  install -d "$pkgdir/usr/share/doc/$pkgname"
  cp -a readme doc/{html,images} "$pkgdir/usr/share/doc/$pkgname"

  # license
  install -d "$pkgdir/usr/share/licenses/$pkgname"
  tail -n26 readme > "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

# vim:set ts=2 sw=2 et:

This package is used on allan-simon/linthesia. I have to tweak configure.ac to use it due to librtmidi and rtmidi oddity:

https://github.com/albfan/linthesia/blob/master/configure.ac#L17

but in a comment from AUR you say there is rtmidi.pc on last revision

https://aur.archlinux.org/packages/rtmidi/

that makes sense and that way I can avoid tweaking configure.ac, but I cannot find that file. Is there another active development repo outside https://github.com/thestk/rtmidi?