Power Query and splitting by multiple whitespace

Experiment with SplitByTextWhitespace.md

This function works sort of like calling Regex.Split with this regex

\s+

Here's fun way to experiment

let
    // convert most things to a single string, to preview multiple steps at the same time
    Csv = (str as list) => 
        Text.Combine( List.Transform(str, Text.From ), ", "),


    Summary = [    
            // to make it crazy, test mixing multiple kinds of whitespace in a single separator
            // 0x20 is space, lf is a line ending  
            str = "123   45.6566#(tab,lf)213#(0020)#(0020)#(0020)99#(lf)#(0020)#(0020)1234",
            
            t1 = Text.SplitAny(str, " "),
            t1_ = Csv( t1 ),

            // The function name is pretty long. You can reuse a shorter alias. 
            SplitSpaces = Splitter.SplitTextByWhitespace(QuoteStyle.None),
            
            t2 = SplitSpaces( str ),
            t2_ = Csv( t2 )
    ]
in
    Summary

Is there context ?

I wrote this for a reddit question

let
        Source = Web.Contents("https://lib.stat.cmu.edu", [ RelativePath = "/datasets/boston" ] ),
        Lines = Lines.FromText(Text.FromBinary(Source)),
        
        Headers = List.Transform( 
            List.Range(Lines, 7, 14),
            each Text.BeforeDelimiter( Text.Trim(_), " ") ),
        
        DataRecords = List.Transform(
            List.Split( List.Skip(Lines, 22), 2 ),
            each Splitter.SplitTextByWhitespace(QuoteStyle.None)( 
                Text.Trim(Text.Combine(_, " ")) )        
        ),
        DataTable = Table.FromRows(DataRecords, Headers)
    in
        DataTable