PKGBUILD for jabberd2

PKGBUILD.sh

# Maintainer: Gaetan Bisson <gaetan.bisson@loria.fr>
# Edited by Colin Shea <colin@evaryont.me>
# ---
# Remember to remove the `.sh' from the filename. it's there to help Gist
# syntax highlight this whole shebang.
#
# See my blog post for more info: http://mindtables.heroku.com/2010/05/18/compiling-jabberd-2-on-arch/

pkgname=jabberd2
pkgver=2.2.9                                                                                                           
pkgrel=3
pkgdesc='Scalable, architecturally sound, and extensible XMPP server - successor to jabberd14'
arch=('i686' 'x86_64')
url='http://codex.xiaoka.com/wiki/jabberd2:start'
license=('GPL')
depends=('expat' 'gsasl' 'zlib' 'udns' 'openssl' 'libidn' 'sqlite3')
source=("http://codex.xiaoka.com/pub/jabberd2/releases/jabberd-$pkgver.tar.bz2"
        'rc.d')
md5sums=('bfc0fa473c2a453fcbba4f95f28c5d70'
         '23369d99be7ea46a15c25807eb27e4a0')
backup=('etc/jabberd/c2s.xml'
        'etc/jabberd/jabberd.cfg'
        'etc/jabberd/router-filter.xml'
        'etc/jabberd/router-users.xml'
        'etc/jabberd/router.xml'
        'etc/jabberd/s2s.xml'
        'etc/jabberd/sm.xml'
        'etc/jabberd/templates/roster.xml')

install=install

build() {
  cd "$srcdir/jabberd-$pkgver"

  ./configure \
    --prefix=/usr --localstatedir=/var/lib --sysconfdir=/etc/jabberd \
    --enable-developer \
    --enable-debug \
    --enable-ssl \
    --enable-pam \
    --enable-fs \
    --enable-superseded \
    --enable-experimental \
    --enable-sqlite \
    --enable-mysql=no \
    --enable-pgsql=no \
    --enable-db=no \
    --enable-oracle=no \
    --enable-ldap=no \
    --enable-anon=no

  make || return 1
  make DESTDIR="$pkgdir" install

  install -D -m 755 ../rc.d "$pkgdir/etc/rc.d/jabberd"
  install -d -m 700 "$pkgdir/var/lib/jabberd"
  cp -r tools "$pkgdir/var/lib/jabberd/"
}