Add "Open with VSCode" to windows explorer context menu of folders and files - windows 7, 10 (auto elevate UAC)

Open with VSCode.vbs

On Error Resume Next

' 1. Change this to your Visual Studio Code file path.
path = "D:\Program Files\VSCode\Code.exe"

' 2. Optional - Change keyboard shortcut here, for example: "F" if you like.
shortcut = "F"

Sub ElevateUAC
    If Not WScript.Arguments.Named.Exists("elevated") Then
        With CreateObject("Shell.Application")
        .ShellExecute "wscript.exe", """" & _
            WScript.ScriptFullName & """ /elevated", "", "runas", 1
            WScript.Quit
        End With
    End If
End Sub

Call ElevateUAC

Set shell = CreateoBject("WScript.shell")
result = shell.Popup("Yes  -  Install" & vbCrLf & "No  -  Uninstall", 0, "Add " & chr(34) & "Open with VSCode" & chr(34) & " ?", vbYesNoCancel + vbQuestion)

If result = vbYes Then
    shell.RegWrite "HKEY_CLASSES_ROOT\*\shell\Open with VSCode\", "VSCode(&" & shortcut & ")", "REG_SZ"
    shell.RegWrite "HKEY_CLASSES_ROOT\*\shell\Open with VSCode\Icon", path & ",0", "REG_EXPAND_SZ"
    shell.RegWrite "HKEY_CLASSES_ROOT\*\shell\Open with VSCode\command\", path & " " & chr(34) & "%1" & chr(34), "REG_SZ"

    shell.RegWrite "HKEY_CLASSES_ROOT\Folder\shell\Open with VSCode\", "VSCode(&" & shortcut & ")", "REG_SZ"
    shell.RegWrite "HKEY_CLASSES_ROOT\Folder\shell\Open with VSCode\Icon", path & ",0", "REG_EXPAND_SZ"
    shell.RegWrite "HKEY_CLASSES_ROOT\Folder\shell\Open with VSCode\command\", path & " " & chr(34) & "%1" & chr(34), "REG_SZ"
ElseIf result = vbNo Then
    shell.RegDelete "HKEY_CLASSES_ROOT\*\shell\Open with VSCode\command\"
    shell.RegDelete "HKEY_CLASSES_ROOT\*\shell\Open with VSCode\Icon"
    shell.RegDelete "HKEY_CLASSES_ROOT\*\shell\Open with VSCode\"

    shell.RegDelete "HKEY_CLASSES_ROOT\Folder\shell\Open with VSCode\command\"
    shell.RegDelete "HKEY_CLASSES_ROOT\Folder\shell\Open with VSCode\Icon"
    shell.RegDelete "HKEY_CLASSES_ROOT\Folder\shell\Open with VSCode\"
Else
    WScript.Quit
End If