LXD container for AdGuardHome capable running with cgroups v1

flake.nix

# Install with:
# incus image import --alias nixos/adguard-home \
#   $(nix build .#nixosConfigurations.adguard-home.config.system.build.metadata --print-out-paths)/tarball/nixos-system-x86_64-linux.tar.xz \
#   $(nix build .#nixosConfigurations.adguard-home.config.system.build.tarball --print-out-paths)/tarball/nixos-system-x86_64-linux.tar.xz
{
  description = "AdGuardHome Container";
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-23.11"; # The systemd supporting cgroups v1
    nixpkgs-unstable.url = "github:nixos/nixpkgs/nixpkgs-unstable";
  };
  outputs = { self, nixpkgs, nixpkgs-unstable, ... }:
  {
    nixosConfigurations = {
      adguard-home = nixpkgs.lib.nixosSystem rec {
        system = "x86_64-linux";
        modules = [
          "${nixpkgs}/nixos/modules/virtualisation/lxc-container.nix"
          (
            { pkgs, ... }:
            {
              nixpkgs.overlays = [
                (self: super: {
                  adguardhome = (import nixpkgs-unstable { inherit system; }).adguardhome;
                })
              ];
              services.adguardhome = {
                enable = true;
                mutableSettings = true;
              };
              services.sshd.enable = false;
              networking.firewall.enable = false;
            }
          )
        ];
      };
    };
  };
}