ExtractInterfaceProcessor.xtend

class ExtractInterfaceProcessor extends AbstractClassProcessor {

  override doRegisterGlobals(ClassDeclaration cls, RegisterGlobalsContext context) {
    context.registerInterface(cls.qualifiedInterfaceName)
  }

  override doTransform(MutableClassDeclaration cls, extension TransformationContext context) {
    findInterface(cls.qualifiedInterfaceName) => [ iface |
      cls.declaredMethods.filter [
        visibility == Visibility::PUBLIC
        static == false
      ].forEach [ method |
        iface.addMethod(method.simpleName) [ extracted |
          extracted.visibility = method.visibility
          extracted.returnType = method.returnType
          method.parameters.forEach[extracted.addParameter(simpleName, type)]
          extracted.docComment = method.docComment
          extracted.exceptions = method.exceptions
        ]
      ]
      iface.addAnnotation(typeof(ImplementedBy).findTypeGlobally) => [
        set("value", cls.newTypeReference)
      ]
    ]
  }
  
  //def qualifiedInterfaceName() {} omitted
}