usage: jq '.' -s -R oldzuse.hoon | lsc -je "(require './retag.ls') @" | jq -r '.' > newzuse.hoon

retag.ls

RANGE=[ '(2)', '++  zuse']

strip_tags = (.filter -> it isnt /^( |::)*  \+\+[a-z0-9:]*$/)
retag = (untagged)->
  stack = []
  already_tagged = {}
  res = []; emit = (-> res.push it)
  started = no
  for untagged
    if ..includes RANGE[0]
      started = yes
    if ..includes RANGE[1]
      started = no
    if !started
      emit ..
      continue
      
    [dent] = ..match /^[ ]*/
    pad = -> (dent + "::" + " "*80).slice 0, 56
    while stack[0]?.dent >= dent => stack.shift!
    
    [,tag]  = (..match /:: *\+\+([a-z0-9:]+)/) ? []
    if tag
      already_tagged[tag] = yes

    [,arm] = (..match /[ ]*\+\+  ([a-z0-9]+)/) ? []
    if arm
      stack
      stack.unshift {arm,dent}
      cur = (stack.map (.arm)) * ':'
      unless already_tagged[cur]
        out = pad! + "::  ++" + cur 
        while out.length > 80
          out -= /[a-z0-9]+:?$/
        emit out

    emit ..
  res
  
module.exports = (input)->
  (retag strip_tags (input / \\n)) * \\n