distinctive - choose how to determine distinct items in Clojure

distinct.clj

(defn distinctive
  "Like clojure.core/distinct, but can take a function f by which distinctiveness is calculated,
   giving similar semantics to sort-by"
  ([coll] (distinctive identity coll))
  ([distinction-fn coll]
   (let [step (fn step [xs seen]
                (lazy-seq
                 ((fn [[f :as xs] seen]
                    (when-let [s (seq xs)]
                      (if (contains? seen (distinction-fn f))
                        (recur (rest s) seen)
                        (cons f (step (rest s) (conj seen (distinction-fn f)))))))
                 xs seen)))]
     (step coll #{}))))

example.clj

;; behaves like distinct with no distinctiveness-fn

user> (distinctive [{:name "foos" :val "ball"}
                    {:name "epic" :val "fail"}
                    {:name "foos" :val "fail"}])
                                                                                             
;; ({:name "foos", :val "ball"} {:name "epic", :val "fail"} {:name "foos", :val "fail"})


;; accepts a distinctiveness-fn which is used to determine if we've seen an element before

user> (distinctive :name 
                   [{:name "foos" :val "ball"}
                    {:name "epic" :val "fail"}
                    {:name "foos" :val "fail"}])
                                                                                             
;; ({:name "foos", :val "ball"} {:name "epic", :val "fail"})