Update 'commentstring' in HTML files

commentstring.vim

" ~/.vim/autoload/commentstring.vim

 function! s:matchcontext(stack, context) abort
	for group in split(a:context, ',')
		if group[0] == '!'
			if index(a:stack, group[1:]) != -1
				return 0
			endif
		else
			if index(a:stack, group) == -1
				return 0
			endif
		endif
	endfor

  return 1
endfunction

function! commentstring#update(contexts) abort
	let stack = synstack(line('.'), col('.'))
	let stack = map(stack, 'synIDattr(v:val, "name")')

	for [context, commentstring] in items(a:contexts)
		if s:matchcontext(stack, context)
			execute 'setlocal commentstring=' . commentstring
			return
		endif
	endfor

	execute 'setlocal commentstring=' . a:contexts.default
endfunction

html.vim

"~/.vim/after/ftplugin/html.vim

let b:commentstrings = {
	\ 'javaScript,!htmlScriptTag': '//\ %s',
	\ 'cssStyle,!htmlTag': '/*\ %s\ */',
	\ 'default': '<!--\ %s\ -->',
\ }

augroup html_auto_commentstring
	autocmd!
	autocmd CursorMoved <buffer> call commentstring#update(b:commentstrings)
augroup END