paho-client.coffee

#= require paho

freezer =
  randomToken: ->
    Math.random().toString(36).substr(2)

  id: ->
    $('body').data('freezer-id').replace(/-/g,"")

  domain: ->
    $('body').data('xively-credentials-domain')

  xiserviceinstance: ->
    $('body').data('xively-credentials-serviceinstance')

  username: ->
    $('body').data('xively-credentials-username')

  password: ->
    $('body').data('xively-credentials-password')

  subscribe_channel: ->
    "/v3/service_instances/#{ freezer.xiserviceinstance() }/domains/#{ freezer.domain() }/devices/#{ freezer.id() }/queues/messagesOUT"

paho =

  setupClient: ->
    paho.client ||= new Messaging.Client("v3mqtt.xively.com", 443, freezer.randomToken() )

  connect: ->
    options =
      #connection attempt timeout in seconds
      timeout: 3
      userName: freezer.username()
      password: freezer.password()
      useSSL: true
      #Gets Called if the connection has successfully been established
      onSuccess: ->
        console.log "Connected"
        console.log freezer.subscribe_channel()
        paho.client.subscribe(freezer.subscribe_channel(), qos: 0)

      #Gets Called if the connection could not be established
      onFailure: (message) ->
        console.log "Connection failed: " + message.errorMessage

    paho.client.connect options
    paho.client.onMessageArrived = (message) ->
      try
        console.log message.payloadString
        json = JSON.parse(message.payloadString)
      catch e
        console.log e
    paho.client.onConnectionLost = (message) ->
      console.log("Connection Lost")
      if message != 0
        paho.setupClient()
        paho.connect()

$ ->
  paho.setupClient()
  paho.connect()