systemtestportal-webapp-2.0.0.ebuild

# Copyright 2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

EGO_VENDOR=(
		"github.com/go-xorm/builder 1d658d7596c25394aab557ef5b50ef35bf706384"
		"github.com/go-xorm/core ccc80c1"
		"github.com/go-xorm/xorm 1f39c59"
		"github.com/gorilla/context 08b5f42"
		"github.com/gorilla/securecookie e59506c"
		"github.com/gorilla/sessions f57b7e2"
		"github.com/hashicorp/errwrap 8a6fb52"
		"github.com/hashicorp/go-multierror 886a7fb"
		"github.com/dimfeld/httptreemux a454a10"
		"github.com/jordan-wright/email 94ae17d"
		"github.com/jung-kurt/gofpdf 8060f83"
		"github.com/pelletier/go-toml 728039f"
		"github.com/mattn/go-sqlite3 c7c4067"
		"github.com/microcosm-cc/bluemonday 506f3da"
		"github.com/nicksnyder/go-i18n 3c6ee90"
		"github.com/pkg/errors ba968bf"
		"github.com/prometheus/client_golang 50c4339"
		"github.com/rubenv/sql-migrate 54bad0a"
		"github.com/unrolled/secure 76e6d4e"
		"github.com/urfave/negroni c6a59be"
		"gitlab.com/silentteacup/congo 3efd6c74"
		"golang.org/x/crypto 20be4c3 github.com/golang/crypto"
		"golang.org/x/net f3200d1 github.com/golang/net"
		"golang.org/x/text f21a4df github.com/golang/text" # v0.3.0
		"github.com/golang/protobuf b5d812f"
		"gopkg.in/russross/blackfriday.v2 d3b5b03 github.com/russross/blackfriday"
		"github.com/beorn7/perks 4b2b341"
		"github.com/go-ini/ini c856070"
		"github.com/prometheus/client_model fd36f42"
		"github.com/prometheus/common cfeb6f9"
		"github.com/prometheus/procfs 65bdadf"
		"github.com/matttproud/golang_protobuf_extensions c12348c"
		"gopkg.in/gorp.v1 6a667da github.com/go-gorp/gorp"
		"github.com/shurcooL/sanitized_anchor_name 7bfe4c7"
		"gopkg.in/yaml.v2 51d6538 github.com/go-yaml/yaml"
)

inherit user golang-build golang-vcs-snapshot

EGO_PN="gitlab.com/stp-team/${PN}"
MY_PV="v${PV}-rc13"
ARCHIVE_URI="
	https://gitlab.com/stp-team/${PN}/-/archive/${MY_PV}/${PN}-${MY_PV}.tar.gz
	${EGO_VENDOR_URI}
"

KEYWORDS="~amd64 ~x86"

DESCRIPTION="A web application that allows to create, run and analyze manual system tests."
HOMEPAGE="http://www.systemtestportal.org"
SRC_URI="${ARCHIVE_URI}"
LICENSE="GPL-3"
SLOT="0"
IUSE=""

DEPEND=""
RDEPEND="${DEPEND}"
BDEPEND=""

pkg_setup() {
	enewgroup stp
	enewuser stp -1 -1 /var/lib/${PN} stp
}

src_compile() {
	pushd src/${EGO_PN} || die
	GOPATH="${S}" go build ./cmd/stp || die
	GOPATH="${S}" go build ./cmd/stp-create-projects || die
	GOPATH="${S}" go build ./cmd/stp-create-users || die
	popd || die
}

src_install() {
	pushd src/${EGO_PN} || die
	dobin stp
	dobin stp-create-projects
	dobin stp-create-users
	insinto "/usr/share/${PN}"
	doins -r migrations
	doins -r static
	doins -r templates
	popd || die
}