Patched PKGBUILD to build telegram-cli

PKGBUILD

# Maintainer: Tom Richards <[email protected]>
# Contributor: Andy Weidenbaum <[email protected]>

pkgname=telegram-cli-git
pkgver=r1043.160231b
pkgrel=1
pkgdesc="Telegram messenger CLI"
arch=('i686' 'x86_64')
url="https://github.com/vysheng/tg"
license=('GPL2')
depends=('libconfig' 'libevent' 'lua' 'jansson')
makedepends=('git')
conflicts=('telegram-cli')
provides=('telegram-cli')

source=("$pkgname"::'git+https://github.com/vysheng/tg'
        'fix-interface.patch'::'https://github.com/rnhmjoj/tg/commit/9e14543c8ac4f9dd72567e09889d3ebf223b4f66.patch')
sha256sums=('SKIP'
            'cc17c9e614945cb995f440a1b663e1124da1a4ce39f405dd18850d9b58df4406')

pkgver() {
    cd "$srcdir/$pkgname"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
    cd $srcdir/$pkgname
    patch -p1 -i ../fix-interface.patch
}

build() {
    cd "$srcdir/$pkgname"
    git submodule update --init --recursive
    ./configure
    make
}

package() {
    cd "$srcdir/$pkgname"
    install -Dm644 tg-server.pub ${pkgdir}/etc/telegram-cli/server.pub
    install -Dm755 bin/telegram-cli ${pkgdir}/usr/bin/telegram-cli
}

Thanks a lot!!!!!!!!!!!!!!!