Example of using the Clojure Lacij library to display the content of an XML file

gistfile1.clj

(ns lacij.examples.display-xml
  (:use lacij.edit.graph
        lacij.view.graphview
        lacij.layouts.layout
        clojure.pprint)
  (:require [clojure.xml :as xml]))

(defn node-text
  [xml]
  (if (string? xml)
    xml
    (name (:tag xml))))

(defn get-children
  [xml]
  (if (string? (:content xml))
    ()
    (:content xml)))

(defn add-children
  [g children parent-id]
  (reduce (fn [g child]
            (let [node-id (genid)]
              (-> g
                  (add-node node-id (node-text child))
                  (add-edge (geneid) node-id parent-id)
                  (add-children (get-children child) node-id))))
          g
          children))

(defn build-graph
  [xml]
  (let [g (graph :width 400 :height 400)
        nid (genid)
        g (add-node g nid (node-text xml))]
    (-> g
        (add-children (:content xml) nid)
        (layout :hierarchical)
        (build))))

(defn -main []
  (let [xml (clojure.xml/parse "/tmp/t1.xml")
        g (build-graph xml)]
    (export g "/tmp/xml.svg")))