yandex-browser-PKGBUILD

# Maintainer: Alexander Konarev <[email protected]>
# Contributor: Vorbote <https://aur.archlinux.org/user/vorbote/>

pkgname=yandex-browser
pkgver=16.2.0.1818_1.beta
pkgrel=1
pkgdesc="The web browser from Yandex (beta version!).
 It's browser that combines a minimal design with sophisticated technology to make the web faster, safer, and easier."
arch=('x86_64')
url='http://browser.yandex.ru/beta/'
license=('custom')
options=(!strip)
depends=('gtk2' 'gconf' 'desktop-file-utils' 'nss' 'alsa-lib' 'libxkbfile' 'libxtst' 'libxss')
optdepends=('chromium-pepper-flash: plugin for viewing flash videos')
conflicts=('yandex-browser-beta')
install='yandex-browser.install'

source=("$pkgname.deb::http://browser.yandex.ru/download/?beta=1&os=linux&x64=1&package=deb&full=1")
sha256sums=('ace4ecfc914b2e0a634353c6049d9e9142d63ffcfa5c4fa92a06a9b438307adc')

pkgver(){
  cd "$srcdir"
  tar -xvzf control.tar.gz > /dev/null
  echo "$(cat control | grep ^Version: | cut -d' ' -f2 | tr '-' '_')".beta
}

prepare() {
  cd "$srcdir"
  tar -xpJf data.tar.xz
}

package() {
  cd "$srcdir"

  cp -a --reflink=auto opt usr "$pkgdir"

  mkdir -p "$pkgdir"/usr/lib/pepperflashplugin-nonfree/
  ln -s /usr/lib/PepperFlash/libpepflashplayer.so "$pkgdir"/usr/lib/pepperflashplugin-nonfree/libpepflashplayer.so
}