Script batch para build de pacotes de temas do ExtJs 4.2

sencha_package_build.bat

:: Script para build dos packages de temas do ExtJs 4.2
:: Utiliza Sencha cmd e Compass

@echo off
title Build dos temas do Centris

:: Caminho para pasta packages
set packages_path=%CD%\packages

:: Comando de build
set build_cmd=sencha package build

:: Argumentos a passar para o comando de build
:: -c = clean: limpa a pasta build antes de executar
set build_args=-c

:: Primeiro, verifica se caminho existe
if not exist %packages_path% (
    echo -------------------------------------------------------------------------
    echo ATENCAO: BUILD NAO GERADO!
    echo Caminho %packages_path% nao encontrado.
    echo Verifique se esta no diretorio correto.
    echo -------------------------------------------------------------------------
    set /p =
    exit /b
)

:: Depois verifica se existe o comando sencha disponível
sencha > nul
if %errorlevel%==9009 (
    echo -------------------------------------------------------------------------
    echo ATENCAO: BUILD NAO GERADO!
    echo Sencha Cmd nao instalado.
    echo Obtenha a ultima versao em www.sencha.com/products/sencha-cmd/.
    echo -------------------------------------------------------------------------
    set /p =
    exit /b
)

:: Então, executa os builds para cada diretorio sob "packages/"
for /f "tokens=*" %%p in ('dir /b /ad-h %packages_path%') do (
    echo -------------------------------------------------------------------------
    echo Gerando build para "%%p"
    echo -------------------------------------------------------------------------

    pushd %packages_path%\%%p
    call %build_cmd% %build_args%
)

echo -------------------------------------------------------------------------
echo Terminado processo de build!
echo -------------------------------------------------------------------------

set /p =
exit /b