ZSH prompt with Git and AWS profile status

prompt.zsh

# original script credit: https://github.com/holman/dotfiles

autoload colors && colors

if (( $+commands[git] ))
then
  git="$commands[git]"
else
  git="/usr/bin/git"
fi

git_branch() {
  echo $($git symbolic-ref HEAD 2>/dev/null | awk -F/ {'print $NF'})
}

git_dirty() {
  if $(! $git status -s &> /dev/null)
  then
    echo ""
  else
    if [[ $($git status --porcelain) == "" ]]
    then
      echo "[%{$fg_bold[green]%}$(git_prompt_info)%{$reset_color%}]"
    else
      echo "[%{$fg_bold[red]%}$(git_prompt_info)%{$reset_color%}]"
    fi
  fi
}

git_prompt_info () {
 ref=$($git symbolic-ref HEAD 2>/dev/null) || return
 echo "${ref#refs/heads/}"
}

unpushed () {
  $git cherry -v @{upstream} 2>/dev/null
}

need_push () {
  if [[ $(unpushed) == "" ]]
  then
    echo " "
  else
    echo " with %{$fg_bold[magenta]%}unpushed%{$reset_color%} "
  fi
}

aws_prompt() {
  if [[ -n $AWS_PROFILE ]]; then
    echo "[%{$fg_bold[yellow]%}$AWS_PROFILE%{$reset_color%}] "
  else
    echo ""
  fi
}

directory_name() {
  echo "%{$fg_bold[cyan]%}%1/%\/%{$reset_color%}"
}

prompt_symbol() {
  echo "%{$fg_bold[green]%}→%{$reset_color%} "
}

export PROMPT=$'\n$(directory_name) $(git_dirty)$(need_push)$(aws_prompt)$(prompt_symbol)'