Arbitrary Source Languages in D

brainfuck.d

module brainfuck;

/// Brainfuck memory
struct Memory
{
	private ubyte[] data;

	private void extendTo(size_t i)
	{
		if (i >= data.length) data.length = i + 1;
	}

	ubyte opIndex(size_t i)
	{
		extendTo(i);
		return data[i];
	}

	ubyte opIndexAssign(ubyte c, size_t i)
	{
		extendTo(i);
		return data[i] = c;
	}
}

/// Compile a brainfuck program to D
string compile(string source)
{
	import std.array: appender;
	import std.range.primitives: put;
	import std.algorithm.iteration: map;
	import std.algorithm.mutation: copy;
	import std.utf: byCodeUnit;

	auto result = appender!string;

	put(result, "
		extern(C) int main()
		{
			import core.stdc.stdio;
			import brainfuck: Memory;

			Memory mem;
			size_t p;
	");

	source.byCodeUnit.map!compileOp.copy(result);

	put(result, "
			return 0;
		}
	");

	return result[];
}

/// Translate a single brainfuck operation to D
/// Based on https://en.wikipedia.org/wiki/Brainfuck#Commands
string compileOp(char op)
{
	switch (op)
	{
		case '>': return "p++;\n";
		case '<': return "p--;\n";
		case '+': return "mem[p] = cast(ubyte) (mem[p] + 1);\n";
		case '-': return "mem[p] = cast(ubyte) (mem[p] - 1);\n";
		case '.': return "putchar(mem[p]);\n";
		case ',': return "mem[p] = cast(ubyte) getchar();\n";
		case '[': return "while (mem[p]) {\n";
		case ']': return "}\n";
		default:  return ""; // ignore other characters
	}
}

main.d

import brainfuck;
import sourcelang;

mixin(lang!brainfuck);

__EOF__
[ This program prints "Hello World!" and a newline to the screen, its
  length is 106 active command characters. [It is not the shortest.]

  This loop is an "initial comment loop", a simple way of adding a comment
  to a BF program such that you don't have to worry about any command
  characters. Any ".", ",", "+", "-", "<" and ">" characters are simply
  ignored, the "[" and "]" characters just have to be balanced. This
  loop and the commands it contains are ignored because the current cell
  defaults to a value of 0; the 0 value causes this loop to be skipped.
]
++++++++               Set Cell #0 to 8
[
    >++++               Add 4 to Cell #1; this will always set Cell #1 to 4
    [                   as the cell will be cleared by the loop
        >++             Add 2 to Cell #2
        >+++            Add 3 to Cell #3
        >+++            Add 3 to Cell #4
        >+              Add 1 to Cell #5
        <<<<-           Decrement the loop counter in Cell #1
    ]                   Loop till Cell #1 is zero; number of iterations is 4
    >+                  Add 1 to Cell #2
    >+                  Add 1 to Cell #3
    >-                  Subtract 1 from Cell #4
    >>+                 Add 1 to Cell #6
    [<]                 Move back to the first zero cell you find; this will
                        be Cell #1 which was cleared by the previous loop
    <-                  Decrement the loop Counter in Cell #0
]                       Loop till Cell #0 is zero; number of iterations is 8

The result of this is:
Cell No :   0   1   2   3   4   5   6
Contents:   0   0  72 104  88  32   8
Pointer :   ^

>>.                     Cell #2 has value 72 which is 'H'
>---.                   Subtract 3 from Cell #3 to get 101 which is 'e'
+++++++..+++.           Likewise for 'llo' from Cell #3
>>.                     Cell #5 is 32 for the space
<-.                     Subtract 1 from Cell #4 for 87 to give a 'W'
<.                      Cell #3 was set to 'o' from the end of 'Hello'
+++.------.--------.    Cell #3 for 'rl' and 'd'
>>+.                    Add 1 to Cell #5 gives us an exclamation point
>++.                    And finally a newline from Cell #6

sourcelang.d

module sourcelang;

/// Compile code from `sourceFile` to D using `language`
string lang(alias language, string sourceFile = __FILE__)()
{
	import std.algorithm.searching: find;
	import std.range: drop;

	return language.compile(
		import(sourceFile)
			.find("__EOF__")
			.drop("__EOF__".length)
	);
}