openzone-cursors.nix

{ stdenv
, lib
, fetchFromGitHub
, fetchurl
, pkg-config
, gtk2
, popt
, xlibs
}:
let
  icon-slicer = stdenv.mkDerivation rec {
    pname = "icon-slicer";
    version = "0.3";

    src = fetchurl {
      url = "http://freedesktop.org/software/icon-slicer/releases/icon-slicer-${version}.tar.gz";
      sha256 = "0kdnc08k2rs8llfg7xgvnrsk60x59pv5fqz6kn2ifnn2s1nj3w05";
    };

    nativeBuildInputs = [
      pkg-config
    ];

    buildInputs = [
      gtk2
      popt
    ];

    meta = {
      description = "Utility for generating icon themes and libXcursor cursor themes";
      homepage = "https://www.freedesktop.org/wiki/Software/icon-slicer/";
      license = lib.licenses.mit;
      maintainers = [ ];
    };
  };
in
stdenv.mkDerivation rec {
  pname = "openzone-cursors";
  version = "1.2.9";

  src = fetchFromGitHub {
    owner = "ducakar";
    repo = "openzone-cursors";
    rev = "v${version}";
    sha256 = "02c536mc17ccsrzgma366k3wlm02ivklvr30fafxl981zgghlii4";
  };

  nativeBuildInputs = [
    icon-slicer
    xlibs.xcursorgen
  ];

  installFlags = [
    "DESTDIR=${placeholder "out"}"
  ];

  meta = {
    description = "Mouse cursor theme for X11 and Wayland";
    homepage = "https://github.com/ducakar/openzone-cursors";
    license = lib.licenses.mit;
    maintainers = [ ];
  };
}