Kotlin/Android Maven/Bintray publishing

android-kotlin-library.gradle

buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:3.1.2'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.7.3'
        classpath 'com.github.dcendents:android-maven-gradle-plugin:2.0' // generate Android friendly POM
    }
}

apply plugin: 'com.android.library'
apply plugin: 'kotlin-android'

android {
    compileSdkVersion targetSdk
    defaultConfig {
        minSdkVersion minSdk
        targetSdkVersion targetSdk
        versionCode 1
        versionName version_name
    }
    buildTypes {
        release {
            minifyEnabled false
        }
    }
}

dependencies {
    api deps.kotlin
    api deps.support
}

apply from: "$rootDir/gradle/publish.gradle"
apply from: "$rootDir/gradle/install.gradle"
apply from: "$rootDir/gradle/bintray.gradle"

bintray.gradle

apply plugin: 'com.jfrog.bintray'

Properties properties = new Properties()
properties.load(project.rootProject.file('local.properties').newDataInputStream())

bintray {
    user = properties.getProperty("bintray.user") ?: System.getenv('BINTRAY_USER')
    key = properties.getProperty("bintray.apikey") ?: System.getenv('BINTRAY_API_KEY')

    configurations = ['archives']
    pkg {
        repo = bintrayRepo
        name = bintrayName
        desc = libraryDescription
        websiteUrl = siteUrl
        vcsUrl = gitUrl
        licenses = allLicenses
        publish = true
        publicDownloadNumbers = true
        version {
            desc = libraryDescription
            gpg {
                // Determines whether to GPG sign the files (default: false)
                sign = true
                // The passphrase for GPG signing (optional)
                passphrase = properties.getProperty("bintray.gpg.password") ?: System.getenv('BINTRAY_GPG_PASSWORD')
            }
        }
    }
}

install.gradle

group = publishedGroupId
version = libraryVersion

def isAndroid = project.hasProperty("android")
if (isAndroid) { // Android libraries
    apply plugin: 'com.github.dcendents.android-maven'

    task sourcesJar(type: Jar) {
        classifier = 'sources'
        from android.sourceSets.main.java.srcDirs
    }
} else { // Java libraries
    apply plugin: 'maven'

    task sourcesJar(type: Jar, dependsOn: classes) {
        classifier = 'sources'
        from sourceSets.main.allSource
    }
}

artifacts {
    archives sourcesJar
}

install {
    repositories.mavenInstaller {
        pom {
            project {
                if (isAndroid) packaging 'aar'
                groupId publishedGroupId
                artifactId artifact

                name libraryName
                description libraryDescription
                url siteUrl

                licenses {
                    license {
                        name licenseName
                        url licenseUrl
                    }
                }
                developers {
                    developer {
                        id developerId
                        name developerName
                        email developerEmail
                    }
                }
                scm {
                    connection gitUrl
                    developerConnection gitUrl
                    url siteUrl
                }
            }
        }
    }
}

kotlin-library.gradle

buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.7.3'
    }
}

apply plugin: 'kotlin'

repositories {
    jcenter()
}

dependencies {
    compile deps.kotlin
}

apply from: "$rootDir/gradle/publish.gradle"
apply from: "$rootDir/gradle/install.gradle"
apply from: "$rootDir/gradle/bintray.gradle"

publish-sample.gradle

// See:
// https://github.com/codepath/android_guides/wiki/Building-your-own-Android-library
// For gradle config:
// https://inthecheesefactory.com/blog/how-to-upload-library-to-jcenter-maven-central-as-dependency/en

ext {
    bintrayRepo = 'maven'
    bintrayName = 'android-reactions'

    publishedGroupId = 'io.zla'
    libraryName = 'Android Reactions'
    artifact = project.name // Bintray issue: module name = artifactId

    libraryDescription = 'A Facebook like reactions picker for Android'

    siteUrl = 'https://github.com/zla-io/android-reactions'
    gitUrl = 'https://github.com/zla-io/android-reactions.git'

    libraryVersion = version_name

    developerId = 'pgreze'
    developerName = 'Pierrick Greze'
    developerEmail = '[email protected]'

    licenseName = 'The Apache Software License, Version 2.0'
    licenseUrl = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
    allLicenses = ["Apache-2.0"]
}