git_zsh_prompt.zsh

#!/bin/zsh
#
# DESCRIPTION:
#
#   Set the zsh prompt according to:
#    * the branch/status of the current git repository
#    * the return value of the previous command
#
# USAGE:
#
#   1. Save this file as ~/.git_zsh_prompt
#   2. Add the following line to the end of your ~/.zshrc:
#        source ~/.git_zsh_prompt
#
# AUTHOR:
#   Converted to zsh from bash script (https://gist.github.com/philster/c485d5f26ad787bcbc90) by Phil Wee <[email protected]>
#   https://gist.github.com/philster/6c2e8517b2f03b015a92033473c8068d

# The various ANSI escape codes that we can use to color our prompt.
        RED=$'%{\033[0;31m%}'
     YELLOW=$'%{\033[0;33m%}'
      GREEN=$'%{\033[0;32m%}'
       BLUE=$'%{\033[0;34m%}'
  LIGHT_RED=$'%{\033[1;31m%}'
LIGHT_GREEN=$'%{\033[1;32m%}'
      WHITE=$'%{\033[1;37m%}'
 LIGHT_GRAY=$'%{\033[0;37m%}'
 COLOR_NONE=$'%{\e[0m%}'

# Detect whether the current directory is a git repository.
function is_git_repository {
  git rev-parse --is-inside-work-tree > /dev/null 2>&1
}

# Determine the branch/state information for this git repository.
function set_git_branch {
  # Capture the output of the "git status" command.
  git_status="$(git status 2> /dev/null)"

  # Set color based on clean/staged/dirty.
  if [[ ${git_status} =~ "working tree clean" ]]; then
    state="${GREEN}"
  elif [[ ${git_status} =~ "Changes to be committed" ]]; then
    state="${YELLOW}"
  else
    state="${RED}"
  fi

  # Set arrow icon based on status against remote.
  remote_pattern="^Your branch is (.*) of"
  if [[ ${git_status} =~ ${remote_pattern} ]]; then
    if [[ ${match[1]} == "ahead" ]]; then
      remote="↑"
    else
      remote="↓"
    fi
  else
    remote=""
  fi
  diverge_pattern="^Your branch and (.*) have diverged"
  if [[ ${git_status} =~ ${diverge_pattern} ]]; then
    remote="↕"
  fi

  # Get the name of the branch.
  branch_pattern="^On branch ([^[:space:]]*)"
  if [[ ${git_status} =~ ${branch_pattern} ]]; then
    branch=${match[1]}
  fi

  # Set the final branch string.
  BRANCH=" ${state}(${branch})${remote}${COLOR_NONE}"
}

# Return the prompt symbol to use, colorized based on the return value of the
# previous command.
function set_prompt_symbol () {
  if test $1 -eq 0 ; then
      PROMPT_SYMBOL="%#"
  else
      PROMPT_SYMBOL="${RED}%#${COLOR_NONE}"
  fi
}

# Set the full zsh prompt.
function set_zsh_prompt () {
  # Set the PROMPT_SYMBOL variable. We do this first so we don't lose the 
  # return value of the last command.
  set_prompt_symbol $?

  # Set the BRANCH variable.
  if is_git_repository ; then
    set_git_branch
  else
    BRANCH=''
  fi

  # Set the zsh prompt variable.
  PS1="%m:%1~ %n${BRANCH} ${PROMPT_SYMBOL} "
}

# Tell zsh to execute this function just before displaying its prompt.
precmd_functions+=(set_zsh_prompt)