deriv

deriv.scm

(define (deriv exp var)
  (define (variable? x)
    (symbol? x))
  (define (same-variable? v1 v2)
    (and (variable? v1) (variable? v2) (eq? v1 v2)))
  (define (=number? exp num)
    (and (number? exp) (= exp num)))
  (define (make-sum a1 a2)
    (cond ((=number? a1 0) a2)
          ((=number? a2 0) a1)
          ((and (number? a1) (number? a2)) (+ a1 a2))
          (else (list '+ a1 a2))))
  (define (make-product m1 m2)
    (cond ((or (=number? m1 0) (=number? m2 0)) 0)
          ((=number? m1 1) m2)
          ((=number? m2 1) m1)
          ((and (number? m1) (number? m2)) (* m1 m2))
          (else (list '* m1 m2))))
  (define (make-exponentiation b e)
    (cond ((or (=number? b 1) (=number? e 0)) 1)
          ((=number? e 1) b)
          ((and (number? b) (number? e) (expt b e)))
          (else (list '** b e))))
  (define (sum? x)
    (and (pair? x) (eq? (car x) '+)))
  (define (addend s) (cadr s))
  (define (augend s)
    (if (null? (cdddr s))
        (caddr s)
        (cons '+ (cddr s))))
  (define (product? x)
    (and (pair? x) (eq? (car x) '*)))
  (define (multiplier p) (cadr p))
  (define (multiplicand p)
    (if (null? (cdddr p))
        (caddr p)
        (cons '* (cddr p))))
  (define (exponentiation? exp)
    (and (pair? exp) (eq? (car exp) '**)))
  (define (base exp) (cadr exp))
  (define (exponent exp) (caddr exp))
  (cond ((number? exp) 0) ; dc/dx = 0 для констант и переменных, отличных от x
        ((variable? exp)
         (if (same-variable? exp var) 1 0)) ; dx/dx = 1 иначе dc/dx = 0
        ((sum? exp)                     ; d(u+v)/dx = du/dx + dv/dx
         (make-sum (deriv (addend exp) var)
                   (deriv (augend exp) var)))
        ((product? exp)               ; d(uv)/dx = v(du/dx) + u(dv/dx)
         (make-sum
          (make-product (multiplier exp)
                        (deriv (multiplicand exp) var))
          (make-product (multiplicand exp)
                        (deriv (multiplier exp) var))))
        ((exponentiation? exp)          ; d(u**n)/dx = nu**(n-1)(du/dx)
         (make-product (make-product (exponent exp)
                                     (make-exponentiation (base exp)
                                                          (make-sum (exponent exp)
                                                                    -1)))
                       (deriv (base exp) var)))
        (else
         (error "неизвестный тип выражения — DERIV " exp))))