gnucash-dev PKGBUILD for 2.7.3 gnucash development version depending on webkit2gtk and gtk3

PKGBUILD

# $Id$
# Maintainer: Pieter Lenaerts <pieter dot lenaerts at gmail.com>
# Contributer: Jeb Rosen <[email protected]>
# Contributor: Juergen Hoetzel <[email protected]>
# Contributor: Mark Schneider <[email protected]>

pkgname=gnucash-dev
pkgver=2.7.2
pkgrel=1
pkgdesc="A personal and small-business financial-accounting application (GTK3 development version)"
arch=('i686' 'x86_64')
url="http://www.gnucash.org"
license=("GPL")
conflicts=('gnucash' 'gnucash-gtk3-git')
provides=('gnucash')
depends=('guile2.0' 'slib' 'libdbi-drivers' 'libmariadbclient' 'postgresql-libs' 'aqbanking' 'desktop-file-utils' 'webkit2gtk' 'libgnome-keyring' 'dconf' 'boost-libs')
makedepends=('intltool' 'boost' 'swig' 'gmock' 'gtest' 'gconf' 'cmake')
optdepends=('evince: for print preview'
	    'yelp: help browser'
            'perl-finance-quote: for stock information lookups'
            'perl-date-manip: for stock information lookups')
options=('!emptydirs')
source=("https://github.com/Gnucash/gnucash/releases/download/${pkgver}/gnucash-${pkgver}.tar.bz2"
        "cmake-dbd-dir.patch")
md5sums=('3bc16e04812d6b2ca921f04bd0702764'
         'b26c729d6f149322c1276f7922f22ef8')
sha1sums=('2c0853eda715f73d78815181f687830b30def1bc'
	  '04d897a110990a6c5401e80a238a54b198c40835')
sha256sums=('baa6bae13918da62be58fe09d904ccf38893607e57dae4eba53db4ff96ab61b3'
            '307db159d761aceb1d13b3df193c2f5231e49c110f971e7e9e26b40f425e1177')

build() {
  cd "${srcdir}/gnucash-${pkgver}"

  mkdir -p build
  cd build
  cmake .. \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=/usr/lib \
    -DCMAKE_INSTALL_LIBEXECDIR=/usr/lib \
    -DWITH_OFX=ON \
    -DWITH_AQBANKING=ON \
    -DCMAKE_BUILD_TYPE=RelWithDebInfo

  make VERBOSE=1
}

package() {
  cd "${srcdir}/gnucash-${pkgver}/build"

  # make install fails with parallel make, see
  # https://bugzilla.gnome.org/show_bug.cgi?id=644896#c11
  # using -j1 instead
  MAKEFLAGS="${MAKEFLAGS} -j1" make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR="${pkgdir}" install

#  cd libgnucash/doc/design
#  make DESTDIR="${pkgdir}" install-info
  rm -f "${pkgdir}"/usr/share/glib-2.0/schemas/*.compiled

  install -dm755 "${pkgdir}/usr/share/gconf/schemas"
  gconf-merge-schema "${pkgdir}/usr/share/gconf/schemas/gnucash.schemas" --domain gnucash "${pkgdir}"/etc/gconf/schemas/*.schemas
  rm -f "${pkgdir}"/etc/gconf/schemas/*.schemas

  # Delete the gnucash-valgrind executable because the source files
  # are not included with the package and the executable is hardlinked
  # to the location that it was built at.
  rm -f "${pkgdir}"/usr/bin/gnucash-valgrind
}