simple model with properties and delegation

collection.coffee

class Collection
  constructor: (items) ->
    @all = if _.any(items, (item) => item instanceof @modelType)
      items
    else
      (new @modelType(item) for item in items)

  add: (item) ->
    @all.push(item)

  select: (key) ->
    _.select @all, (item) =>
      @_decodeFilter(item, key)

  selectBy: (key, filters...) ->
    _.select @all, (item) =>
      _.include filters, @_decodeFilter(item, key)

  _decodeFilter: (item, key) ->
    func = item[key]
    (if _.isFunction(func) then func.call(item) else func)

window.Collection = Collection

model.coffee

class Delegator
  delegate: ->
    methods = Array.prototype.slice.call(arguments)
    delegate = methods.pop()

    _.each methods, (method) =>
      @[method] = _.bind(delegate[method], delegate)

class Model extends Delegator
  constructor: (attrs) ->
    @_setProperty(key, value) for key, value of attrs

  _setProperty: (property, value) =>
    @[property] = value

window.Model = Model
window.Delegator = Delegator