ndi-sdl PKGBUILD

PKGBUILD

# Maintainer: Daniel Bermond < yahoo-com: danielbermond >
# Contributor: Phillip Schichtel <[email protected]>
pkgname=ndi-sdk
pkgver="3.20171009.r82134"
_libver="3.0.9"
pkgrel=1
pkgdesc="Newtek NDI SDK (binary download)"
arch=('i686' 'x86_64')
url="https://www.newtek.com/ndi/sdk/"
depends=("glibc")
optdepends=("avahi: Required for NDI source search")
makedepends=("poppler")
license=("custom")
provides=("libndi.so" "libndi" "libndi3")
conflicts=("libndi" "libndi3")
options=("!strip")
source=("installer.sh::http://514f211588de67e4fdcf-437b8dd50f60b69cf0974b538e50585b.r63.cf1.rackcdn.com/Utilities/SDK/NDI_SDK_Linux_v2/InstallNDISDK_v3_Linux.sh")
sha256sums=('6fc5d3c3f2d10837187b0db8fb332a88ef7bca311214d7b05e87497789e97a16')

prepare() {
    chmod +x installer.sh
    yes | ./installer.sh
}

package() {
    cd "NDI SDK for Linux"
    
    local majver="${pkgver%%.*}"
    install -D -t "${pkgdir}/usr/lib"  "lib/$CARCH-linux-gnu/libndi.so.${_libver}"
    ln -s "libndi.so.${_libver}" "${pkgdir}/usr/lib/libndi.so.${majver}"
    ln -s "libndi.so.${_libver}" "${pkgdir}/usr/lib/libndi.so"

    install -D -m 644 -t "${pkgdir}/usr/include/${pkgname}" "include/"*
    
    install -d "${pkgdir}/usr/share/${pkgname}" 
    cp -a --no-preserve=owner -t "${pkgdir}/usr/share/${pkgname}" \
        "examples" \
        "logos"
    find "${pkgdir}/usr/share/${pkgname}" -type f -exec chmod 644 "{}" \;

    for f in "${pkgdir}/usr/share/${pkgname}/logos/"*'®'*
    do
        mv -v "$f" "$(sed 's/®/(R)/g' <<< "$f")"
    done

    install -D -m 644 -t "${pkgdir}/usr/share/doc/${pkgname}" "documentation/"*

    pdftotext -layout -q "NDI License Agreement.pdf" LICENSE
    install -D -m 644 -t "${pkgdir}/usr/share/licenses/${pkgname}" LICENSE
}