Macro to generate "value classes" in Haxe

Example.hx

import precog.macro.ValueClass;

class ABC implements ValueClass {
    var a: Int;
    var b: Bool;
    var c: String;
}

/*
class ABC extends ValueClass {
    public var a(default, null): Int;
    public var b(default, null): Bool;
    public var c(default, null): String;

    public function new(a: Int, b: Bool, c: String) {
        this.a = a;
        this.b = b;
        this.c = c;
    }
}
*/

ValueClass.hx

package precog.macro;

import haxe.macro.Expr;
import haxe.macro.Context;

@:remove @:autoBuild(ValueClassImpl.build())
extern interface ValueClass {}

class ValueClassImpl {
#if macro
    public static function build() {
        var fields = Context.getBuildFields();
        var args = [];
        var states = [];
        for (f in fields) {
            switch (f.kind) {
            case FVar(t, _):
                args.push({name: f.name, type: t, opt: false, value: null});
                states.push(macro $p{["this", f.name]} = $i{f.name});
                f.kind = FProp("default", "null", t);
                f.access.push(APublic);
            default:
            }
        }
        fields.push({
            name: "new",
            access: [APublic],
            pos: Context.currentPos(),
            kind: FFun({
                args: args,
                expr: macro $b{states},
                params: [],
                ret: null
            })
        });
        return fields;
    }
#end
}

I ran into the Type not found error with Haxe 4.0.5; I got it to work by specifying the fully qualified macro type name in the @:autoBuild metadata, e.g. "@:autoBuild(my.package.to.ValueClass.ValueClassImpl.build()). Once I did that, everything worked as originally spec'd above (including the extern and @:remove).