PureScript `waitFor` combinator for Aff

Main.purs

module Main where

import Prelude

import Data.Either (Either)
import Data.Int (round)
import Effect (Effect)
import Effect.Aff (Aff, Milliseconds(..), attempt, delay, error, forkAff, joinFiber, killFiber, launchAff_)
import Effect.Class (liftEffect)
import Effect.Class.Console (logShow)
import Effect.Exception (Error)
import Effect.Timer (clearTimeout, setTimeout)


waitFor :: forall r. Aff r -> Milliseconds -> Aff (Either Error r)
waitFor task (Milliseconds timeout_) = do
  let timeout = round timeout_

  taskF <- forkAff task

  timeoutId <- liftEffect $
    setTimeout timeout $ launchAff_ do
      killFiber (error "waitFor: task timed out") taskF

  result <- attempt $ joinFiber taskF
  liftEffect $ clearTimeout timeoutId
  pure result


slow :: Milliseconds -> Aff Int
slow timeout = do
  delay timeout
  pure 42


main :: Effect Unit
main = launchAff_ do
  result <- waitFor (slow (Milliseconds 500.0)) (Milliseconds 1000.0)
  logShow result