aoc2024-day7-fast.scm

(use-modules (srfi srfi-1) (ice-9 textual-ports) (ice-9 peg)
	     (ice-9 pretty-print) (srfi srfi-26) (ice-9 receive))

(define-peg-string-patterns
  "entry <-- number COLON (SPACE number)+ NL
number <-- [0-9]+

COLON < ':'
SPACE < ' '
NL < '\n'
")

(define-peg-pattern top all (peg "entry* !."))


(define (%process-number number)
  (string->number (cadr number)))

(define (%process-entry entry)
  (cons (%process-number (cadr entry))
	(map %process-number (caddr entry))))

(define (process-tree tree)
  (map %process-entry (cdr tree)))



(define (10**digits x)
  (integer-expt 10 (inexact->exact (ceiling (log10 x)))))

(define (try target factors part-2?)
  (cond
   [(< target 0) #f]
   [(null? (cdr factors))
    (eqv? target (car factors))]
   [else
    (or (and part-2?
	     (eqv? (car factors)
		   (remainder
		    target
		    (10**digits (car factors))))
	     (try (quotient target (10**digits (car factors))) (cdr factors) part-2?))
	(and (eqv? 0 (remainder
		      target
		      (car factors)))
	     (try (quotient target (car factors)) (cdr factors) part-2?))
	(try (- target (car factors)) (cdr factors) part-2?))]))


(define (calibration-sum part-2? entries)
  (fold
   + 0
   (map
    (λ (entry)
      (if (try (car entry)
	       (reverse (cdr entry))
	       part-2?)
	  (car entry)
	  0))
    entries)))


(let* ([input (get-string-all (current-input-port))]
       [peg-tree (peg:tree (match-pattern top input))]
       [entries (process-tree peg-tree)])
  (pretty-print (calibration-sum #f entries))
  (pretty-print (calibration-sum #t entries)))