VapourSynth R74

PKGBUILD

# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: sl1pkn07 <sl1pkn07@gmail.com>
# Contributor: jackoneill <cantabile.desu@gmail.com>

pkgname=vapoursynth
pkgver=74
pkgrel=1
pkgdesc='A video processing framework with the future in mind'
arch=(x86_64)
url=http://www.vapoursynth.com/
license=(
  LGPL2.1
  custom:OFL
)
depends=(
  libzimg.so
  python
)
makedepends=(
  cython
  git
  meson-python
  ninja
  python-build
  python-installer
  python-sphinx
)
_tag=140ed20676a2863cd8542030e630b13454035233
source=(
  git+https://github.com/vapoursynth/vapoursynth.git#tag=${_tag}
  0001-unbreak-vsscript-soversion.patch
  vapoursynth.xml
)
b2sums=('85438d4e1ccb88e34d3a46a6891ef8d6a520dcb061a6c4b7acf04708d1c88ffcc5e4d734da31ffb0f96bd61d6b64e82f9222181c0d077a063cccf8b52aaedc01'
        '5f632eea908d65bf9384ee54fcb879d7ca5a2cdef3ad3adefab1a5a44d540c4529e75d242b384d9b6e7e971f1eea35e9b00669ba43d813ad39196b04c426cd52'
        'feae23a22f8589177f30c36bdf21bab93d55a786194d3e0e958537016630d075b82178f60ac840f30ae316a8f87d3fb01f371211f62d1fee9850ee5063561747')

pkgver() {
  cd vapoursynth
  git describe --tags | sed 's/^R//'
}

prepare() {
  cd vapoursynth

  # https://github.com/vapoursynth/vapoursynth/commit/f38b00718b34f293b5b5c9211c12dff8c3714071
  git apply -3 ../0001-unbreak-vsscript-soversion.patch
}

build() {
  cd vapoursynth

  # Build lib for headers and pkg-config file
  arch-meson build-lib
  meson compile -C build-lib

  python -m build --wheel --no-isolation
}

package() {
  cd vapoursynth

  # Install system lib headers and pkg-config
  meson install -C build-lib --destdir "${srcdir}/fakeroot"

  install -d -m755 "${pkgdir}/usr"/{include/vapoursynth,lib/pkgconfig}

  install -Dm 644 "${srcdir}"/fakeroot/usr/include/vapoursynth/*.h -t "${pkgdir}/usr/include/vapoursynth/"
  install -Dm 644 "${srcdir}/fakeroot/usr/lib/pkgconfig/vapoursynth.pc" -t "${pkgdir}/usr/lib/pkgconfig/"

  # Install Python package and symlink to system library
  python -m installer --destdir="$pkgdir" dist/*.whl

  _sitepkgs="$(python -c 'import site; print(site.getsitepackages()[0])')"
  ln -sr "${pkgdir}${_sitepkgs}/vapoursynth/libvapoursynth.so.4" "${pkgdir}/usr/lib/"
  ln -sr "${pkgdir}/usr/lib/libvapoursynth.so.4" "${pkgdir}/usr/lib/libvapoursynth.so"

  install -d -m755 "${pkgdir}${_sitepkgs}/vapoursynth/plugins"

  install -Dm 644 src/core/ter-116n.ofl.txt -t "${pkgdir}"/usr/share/licenses/vapoursynth/
  install -Dm 644 ../vapoursynth.xml -t "${pkgdir}"/usr/share/mime/packages/
}

# vim: ts=2 sw=2 et: