Transition example

transition_example.pp

class profile::app::delicapp (
  $ref     = 'master',
  $version = '1.2',
) {

  include ::tomcat
  include ::java

  tomcat::instance { 'tomcat8':
    catalina_base => '/opt/apache-tomcat/tomcat8',
    source_url    => 'http://mirror.nexcess.net/apache/tomcat/tomcat-8/v8.0.15/bin/apache-tomcat-8.0.15.tar.gz'
  } ->
  tomcat::service { 'tomcat8':
    catalina_base => '/opt/apache-tomcat/tomcat8',
  }

  remote_file { 'plsample.war':
    ensure => present,
    path   => "/opt/staging/plsample-${version}.war",
    source => "http://master/tomcat/plsample-${version}.war",
  } ->
  file { 'plsample.war':
    ensure => symlink,
    target => "/opt/staging/plsample-${version}.war",
    path   => '/opt/apache-tomcat/tomcat8/webapps/plsample.war',
    notify => Tomcat::Service['tomcat8'],
  }

  exec { 'arbitrarily complex upgrade procedure':
    path        => '/usr/bin:/bin',
    command     => 'rm -rf /opt/apache-tomcat/tomcat8/webapps/plsample && sleep 20',
    refreshonly => true,
    subscribe   => File['plsample.war'],
    notify      => Tomcat::Service['tomcat8'],
  }

  transition { 'ensure service stopped for app update':
    resource   => Service['tomcat-tomcat8'],
    attributes => { 'ensure' => 'stopped' },
    prior_to   => File['plsample.war'],
  }

}