Code snippets for http://ryanfunduk.com/flex3-centered-overlays

1.as

import flash.display.Graphics;
import flash.display.BitmapData;
import flash.geom.Matrix;
import flash.events.MouseEvent;

[Embed(source='overlay.png')]
private var Overlay:Class;

private var g:Graphics;
private var bmd:BitmapData;
private var m:Matrix;
private var overlay:Boolean = false;

private function drawPlaceHolder():void {
  g.clear();
  g.lineStyle( 3, 0xDDDDDD, 1 );
  g.drawRect( 0, 0, canvas.width, canvas.height );
  g.endFill();
  g.moveTo( 0, 0 );
  g.lineTo( canvas.width, canvas.height );
  g.moveTo( canvas.width, 0 );
  g.lineTo( 0, canvas.height );
}

public function creationCompleteHandler():void {
  g = canvas.graphics;
  drawPlaceHolder();

  bmd = (new Overlay()).bitmapData;
  m = new Matrix();

  m.translate( ( canvas.width - bmd.width ) >> 1,
               ( canvas.height - bmd.height ) >> 1 );

  canvas.addEventListener( MouseEvent.MOUSE_MOVE,
                           function( e:MouseEvent ):void {
    if( overlay ) { return; } overlay = true;
    g.lineStyle( 0, 0, 0 );
    g.beginBitmapFill( bmd, m, false, true );
    g.drawRect( 0, 0, canvas.width, canvas.height );
    g.endFill();
  } );
  canvas.addEventListener( MouseEvent.ROLL_OUT,
                           function( e:MouseEvent ):void {
    overlay = false;
    drawPlaceHolder();
  } );
}

2.as

import flash.display.Graphics;
import flash.display.BitmapData;
import flash.display.Shape;
import flash.geom.Matrix;
import flash.events.MouseEvent;

[Embed(source='overlay.png')]
private var Overlay:Class;

private var m:Matrix = new Matrix();
private var s:Shape = new Shape();
private var g:Graphics = s.graphics;
private var bmd:BitmapData = new Overlay().bitmapData;

public function creationCompleteHandler( event:Event ):void {
  m.translate( ( image.width - bmd.width ) >> 1,
               ( image.height - bmd.height ) >> 1 );

  g.beginBitmapFill( bmd, m, false, true );
  g.drawRect( 0, 0, image.width, image.height );
  g.endFill();

  image.addEventListener( MouseEvent.MOUSE_MOVE,
                          function( e:MouseEvent ):void {
    if( !image.contains( s ) ) { image.addChild( s ); }
  } );
  image.addEventListener( MouseEvent.ROLL_OUT,
                          function( e:MouseEvent ):void {
    if( image.contains( s ) ) { image.removeChild( s ); }
  } );
}