Poor man's knex/bookshelf pagination

paginate.coffee

Promise = require 'bluebird'

defaultPageSize = 20

paginate = (knex) -> (query, paginationOptions, options) ->

  if query.fetchAll?
    model = query
    query = model.query()

  # Store original query.
  totalQuery = knex.count().from query.clone().as 'inner'
  totalPromise = totalQuery.then (rows) -> rows[0].count

  # Extract options
  { page, pageSize, offset, limit } = paginationOptions

  # Set defaults
  pageSize   ?= defaultPageSize
  offset     ?= 0
  page        = 1 if not page? or page < 1

  # Update vars based on interplay between limit/offset and pagination.
  page       += offset // pageSize

  # Calculate actual limit and offset to be used in query. (Note that the
  # natural concept of a page starts from 1 rather than 0.)
  limit   = limit ? pageSize
  offset += (page - 1) * pageSize

  query.offset offset
  query.limit limit if limit > 0

  return Promise.all([
    model?.fetchAll(options) or query
    totalPromise
  ]).spread (data, total) -> {
    pagination: {
      total, pageSize, offset, limit, page,
      pageCount: Math.ceil(total / pageSize)
    },
    data
  }

module.exports = paginate

Is this still your preferred pagination method? Looking into implementing something on my side.