MELScript to edit Maya mesh UVs by using values

UVCoordinatesEditor.mel

global proc CreateUI() {
    global int $job;
    if (`window -ex _uv_window`) { 
        return;
    }
    $job = `scriptJob -idleEvent UpdateUI`;
    window -t "UV Coordinates Editor" _uv_window;
        columnLayout;
            rowLayout -numberOfColumns 4;        
                text "u";
                floatField -cc "UpdateU" _uv_uField;    
                text "v";
                floatField -cc "UpdateV" _uv_vField;
             setParent ..;
        setParent ..;
    showWindow;
}
global proc UpdateUI() { 
    global float $lastUV[];
    global float $uv[];
    if (!`window -ex _uv_window`) { 
        scriptJob -ro true -idleEvent KillJob;
        return;
    }
    $uv =`polyEditUV -q`;
    if ($uv[0] != $lastUV[0]) {
        floatField -e -v $uv[0] _uv_uField;
        $lastUV[0] = $uv[0];
    }
    if ($uv[1] != $lastUV[1]) {
        floatField -e -v $uv[1] _uv_vField;
        $lastUV[1] = $uv[1];
    }
}
global proc UpdateU() {
    global float $uv[];  
    $uv[0] = `floatField -q -v _uv_uField`;
    polyEditUV -u $uv[0] -r false;
}
global proc UpdateV() {    
    global float $uv[];
    $uv[1] = `floatField -q -v _uv_vField`;
    polyEditUV -v $uv[1] -r false;
}
global proc KillJob() {
    global int $job;
    scriptJob -k $job;
}
CreateUI();

To use the tool, execute the script manually or by adding it to the shelf.
The coordinates window will be updated when a single UV is selected/changed.
Change the values on the coordinates window to change the actual UV coordinates.