jQuery iterator for Haxe

gistfile1.hx

package sample;

import jQuery.JQuery;

class JQueryHelper {
  public static function asIterable(query: JQuery): Iterable<JQuery> {
		return new JQueryIterable(query);
	}
}

private class JQueryIterable {
	private var query: JQuery;

	public function new(query: JQuery) {
		this.query = query;
	}

	public inline function iterator(): Iterator<JQuery> {
		return new JQueryIterator(this.query);
	}
}

private class JQueryIterator {
	private var query: JQuery;
	private var length: Int;
	private var p: Int;

	public function new(query: JQuery) {
		this.query = query;
		this.length = query.length;
		this.p = 0;
	}

	public function hasNext(): Bool {
		return this.p < this.length;
	}

	public function next(): JQuery {
		return new JQuery(this.query[this.p++]);
	}
}

gistfile2.hx

package sample;

import js.Lib;
import jQuery.JQuery;

using Lambda;
using sample.JQueryHelper;

class Main {
    static function main() {
        // JQuery -> Array<String>
        var result = new JQuery(js.Lib.document.body)
          .asIterable()
          .map(function(el: JQuery) { return el.text(); })
          .array()
        ;

        trace(result);
    }
}