_______________ (PuzzleScript Script)

readme.txt

Play this game by pasting the script in http://www.puzzlescript.net/editor.html

script.txt

title _______________
verbose_logging

(let's start an actual dev log instead of one or two people putting a comment here every now and then like with gophers - ncr)
(#0 patrick: base game, all graphics are squares)
(#1 ncrecc: added level 3 and fake border tile, introduced this log (pat's fine with it))
(#2 bagenzo: added level 4 and the collectable)
(#3 TophWells: added level ? and fixed a movement bug )
(#4 Sky: Wanted to add a player3 but just made player2 switched to player1 again, find something interesting. :D )
(#5 [you]: [before you fill this in, copy and paste this exact template into the line below but with the first number + 1])
========
OBJECTS
========

Background
gray

Player1
blue

( the placeholder graphic for this is
blue
00000
.....
00000
.....
00000
so feel free to change it and delete this comment )

Overlay
blue
00000
.....
00000
.....
00000

Switcher
pink

Player2
red

Wall
darkgreen

Goal
green

Collectable (grab all these before you can win)
yellow

Border (meant to represent the level border. can be resprited if someone decides to ditch the "open access to border" aesthetic)
black

Crate
brown
00000
0...0
0...0
0...0
00000


=======
LEGEND
=======

. = Background
# = Wall
p = Player1
r = Player1 and Wall
s = Switcher
q = Player2
g = Goal
! = Switcher
X = Border
c = Collectable
M = Crate
Player = Player1 or Player2


=======
SOUNDS
=======

================
COLLISIONLAYERS
================

Background
Goal
Collectable
Wall, Player2, Border
Overlay
Switcher
Player1, Crate

======
RULES
======

(fake border is as solid as real border)
[ > Player1 | Border ] -> [ Player1 | Border ]

(Interactions between Player2 and Crate have been intentionally left blank)
(Crate can be bumped by one space)
[ > Player1 | Crate | No Crate No Overlay ] -> [ Player1 | Overlay | Crate ]
(Crate slides over overlay)
[ > Player1 | Crate] -> [ Player1 | > Crate] 
[ > Crate | No Crate Overlay ] -> [ Overlay | Overlay > Crate ]

( this could be painting, slime trail, something computer-y, something abstract, etc. depending on the theming )
[ Player1 no Overlay ] -> [ Player1 Overlay ]

(bugfix: don't add extra moves to the undo stack if the player moved into a wall or otherwise skipped their turn)
late [Player1 Overlay] -> [Player1 no Overlay]

late [ Crate Switcher ] [ Player1 ] -> [ ] [  Player2  ]
late [ Player1 Switcher ] [ Crate ]-> [  Player2  ] [ ]
late [ Player1 Switcher ] -> [ Player2 ]

late [ Player2 ] [ Overlay Wall ]    -> [ Player2 ] [ ]
late [ Player2 ] [ Overlay no Wall ] -> [ Player2 ] [ Wall ]

late [ Player2 Collectable ] -> [ Player2 ]

late [ Player2 Switcher ] -> [ Player1 ]


==============
WINCONDITIONS
==============

any Player2
all Player2 on Goal
no Collectable

=======
LEVELS
=======

( feel free to tweak )
(patrick)
.......
...###.
...#...
.q.#g..
...#...
...###.
.......

( feel free to tweak )
(patrick)
...###...
...###...
...###...
s..###..g
...###...
...###...
p..###...

(this should be a relatively early level)
(ncrecc)
pgxxxs.
.#xxx#.
.#xxx#.
..xxx..
..xxx..
#.###.#
#.....#

(introduction to the collectable)
(bagenzo)
....x.....
.p..s.g.c.
....x.....
x.xxxx.xxx
...#.#.#..
.c#.#.##c.
...x.#x#..

(compact level with more collectables)
(TophWells)
x..pc.cs..x
..x.....x..
.cx.c#c.xc.
........x..
xxxc...gxxx

(nano level, don't know where it should be)
(Sky Chan)
sc#cs
##g##
sq#cs

(introduction of the crate. is this too easy)
(blubberquark)
...#.#...
....#.#..
...#.#...
s...#.#.g
.M.#.#...
....#.#..
p..#.#...