4clojure.coffee

casper = require('casper').create
  logLevel: 'debug'
fs = require('fs')

username = casper.cli.args[0]
password = casper.cli.args[1]
currentProblem = 1
problemCount = 173

getProblem = (number) ->
  url = "http://www.4clojure.com/problem/#{ number }"
  @start url, ->
    title       = @evaluate -> jQuery('#prob-title').text()
    description = @evaluate -> jQuery('#prob-desc').text()
    test_cases  = @evaluate -> jQuery('table.testcases .CodeMirror.test').map(-> ";; #{ jQuery(this).text() }").toArray().join("\n")
    solution    = @evaluate -> jQuery('#code-box').val()

    fs.write "#{ number }-#{ title.toLowerCase().replace(/\W/g, '_') }.clj", """
    ;; #{ title }
    ;;
    ;; #{ description }
    ;;
    ;; test cases:
    #{ test_cases }

    #{ solution }
    """
    @echo ">>> got problem #{ number }"

getAllProblems = ->
  if currentProblem <= problemCount
    getProblem.call @, currentProblem
    currentProblem++
    @run getAllProblems
  else
    @echo "downloaded all problems"
    @exit()

casper.start 'https://www.4clojure.com/login', ->
  @fill 'form[action="/login"]', { user: username, pwd: password }, true

casper.run getAllProblems

usage:

casperjs --ignore-ssl-errors=true 4clojure.coffee USERNAME PASSWORD

👍 very nice