Small Animation Utility for CoffeeScript (JavaScript)

animator.coffee

###
animator.coffee
(C) 2014 Shintaro Seki <[email protected]>
The MIT License
###
#
# Usage:
#   fps = 15
#   animator = new Animator fps, (frameCount) ->
#     console.log frameCount
#     animator.stop() if frameCount > fps
#   .run()
#
# References:
# * http://yomotsu.net/blog/2013/01/05/fps.html
#
class Animator
	requestAnimationFrame = do ->
		window.requestAnimationFrame or
		window.webkitRequestAnimationFrame or
		window.mozRequestAnimationFrame or
		window.oRequestAnimationFrame or
		window.msRequestAnimationFrame or
		(cb) -> window.setTimeout cb, 1000.0 / 60.0

	now = window.performance and
		performance.now or
		performance.mozNow or
		performance.msNow or
		performance.oNow or
		performance.webkitNow

	getTime = ->
		now?.call(performance) or Date.now?() or new Date().getTime()

	constructor: (@fps, @fn) -> @isRunning = false

	run: ->
		return if @isRunning
		@isRunning = true
		frameTime = 1000.0 / @fps
		startTime = getTime()
		frameCount = 0
		do loopFn = =>
			requestAnimationFrame loopFn if @isRunning
			currentFrameCount = Math.floor((getTime()-startTime) / frameTime)
			if currentFrameCount > frameCount
				frameCount = currentFrameCount
				@fn frameCount
		@
	
	stop: -> @isRunning = false; @